@echo off
setlocal EnableExtensions

set "SCRIPT_DIR=%~dp0"
set "FRAMEWORK_DIR=%SCRIPT_DIR%ThirdParty\framework-F4-Conversion"
set "UL_SDK=%ULTRALIGHT_SDK_PATH%"

if not defined UL_SDK set "UL_SDK=F:\UltralightSDK"

where xmake >nul 2>&1
if errorlevel 1 (
    echo xmake was not found on PATH.
    exit /b 1
)

if not exist "%FRAMEWORK_DIR%\xmake.lua" (
    echo Framework submodule missing. Run:
    echo   git submodule update --init --recursive ThirdParty/framework-F4-Conversion
    exit /b 1
)

echo Linking Ultralight SDK from:
echo   %UL_SDK%
powershell -NoProfile -ExecutionPolicy Bypass -File "%SCRIPT_DIR%scripts\setup-ultralight-link.ps1" -SdkPath "%UL_SDK%"
if errorlevel 1 (
    echo Failed to link Ultralight SDK.
    exit /b 1
)

cd /d "%FRAMEWORK_DIR%"
echo Configuring PrismaUI_F4...
xmake f --plat=windows --arch=x64 -m release
if errorlevel 1 exit /b 1

echo Building PrismaUI_F4...
xmake build -r PrismaUI_F4
if errorlevel 1 exit /b 1

echo.
echo PrismaUI_F4 build succeeded.
for /r "%FRAMEWORK_DIR%\build" %%F in (PrismaUI_F4.dll) do (
    if exist "%%F" echo   %%F
)

endlocal
exit /b 0